src/lib.nim

   1 import
   2   httpClient,
   3   json,
   4   os,
   5   osproc,
   6   re,
   7   sequtils,
   8   std/[terminal],
   9   strformat,
  10   strutils,
  11   tables
  12
  13 import
  14   config,
  15   types
  16
  17
  18 let
  19   processOptions = {poStdErrToStdOut, poUsePath} # poEchoCmd can be added to options for debugging
  20   PEERTUBE_REGEX = re"videos\/watch\/[0-9a-f]{8}\b-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{4}-\b[0-9a-f]{12}"
  21
  22
  23 proc isInstalled(program: string): bool =
  24   execProcess("which " & program).len != 0
  25
  26
  27 proc selectMediaPlayer*(): string =
  28   let availablePlayers = supportedPlayers.filter(isInstalled)
  29   if len(availablePlayers) == 0:
  30     stderr.writeLine &"Please install one of the supported media players: {supportedPlayers}"
  31     raise newException(OSError, "No supported media player found")
  32   else:
  33     return availablePlayers[0]
  34
  35
  36 proc getPeerTubeMagnetLink(url: string): string =
  37   ## Gets the magnet link of the best possible resolution from PeerTube
  38   let uuid = url.substr(find(url, PEERTUBE_REGEX) + "videos/watch/".len)
  39   let domainName = url.substr(8, find(url, '/', start=8) - 1)
  40   let apiURL = &"https://{domainName}/api/v1/videos/{uuid}"
  41   let client = newHttpClient()
  42   let response = get(client, apiURL)
  43   let jsonNode = parseJson($response.body)
  44   jsonNode["files"][0]["magnetUri"].getStr()
  45
  46
  47 proc presentVideoOptions*(searchResults: SearchResults) =
  48   eraseScreen()
  49   for index, (title, url) in searchResults:
  50     styledEcho $index, ". ", styleBright, fgMagenta, title, "\n", resetStyle, fgCyan, "   ", url, "\n"
  51
  52
  53 func buildPlayerArgs(url: string, options: Table[string, bool], player: string): seq[string] =
  54   let musicOnly = if options["musicOnly"]: "--no-video" else: ""
  55   let fullScreen = if options["fullScreen"]: "--fullscreen" else: ""
  56   filterIt([url, musicOnly, fullScreen], it != "")
  57
  58
  59 proc play*(player: string, options: Table[string, bool], url: string, title: string = "") =
  60   let args = buildPlayerArgs(url, options, player)
  61   if title != "":
  62     styledEcho "\n", fgGreen, "Playing ", styleBright, fgMagenta, title
  63   if "--no-video" in args:
  64     discard execShellCmd(&"{player} {args.join(\" \")}")
  65   else:
  66     discard execProcess(player, args=args, options=processOptions)
  67
  68
  69 func buildMusicDownloadArgs(url: string): seq[string] =
  70   {.noSideEffect.}:
  71     let downloadLocation = &"'{expandTilde(musicDownloadDirectory)}/%(title)s.%(ext)s'"
  72     @["--ignore-errors", "-f", "bestaudio", "--extract-audio", "--audio-format", "mp3",
  73       "--audio-quality", "0", "-o", downloadLocation, url]
  74
  75
  76 func buildVideoDownloadArgs(url: string): seq[string] =
  77   {.noSideEffect.}:
  78     let downloadLocation = &"'{expandTilde(videoDownloadDirectory)}/%(title)s.%(ext)s'"
  79     @["-f", "best", "-o", downloadLocation, url]
  80
  81
  82 proc download*(args: openArray[string], title: string) =
  83   styledEcho "\n", fgGreen, "Downloading ", styleBright, fgMagenta, title
  84   discard execShellCmd(&"youtube-dl {args.join(\" \")}")
  85
  86
  87 func urlLongen(url: string): string = url.replace("youtu.be/", "www.youtube.com/watch?v=")
  88
  89
  90 func rewriteInvidiousToYouTube(url: string): string =
  91   {.noSideEffect.}:
  92     if rewriteInvidiousURLs: url.replace("invidio.us", "www.youtube.com") else: url
  93
  94
  95 func stripZshEscaping(url: string): string = url.strip(chars={'\\'})
  96
  97
  98 func sanitizeURL*(url: string): string =
  99   rewriteInvidiousToYouTube(urlLongen(stripZshEscaping(url)))
 100
 101
 102 proc directPlay*(url: string, player: string, options: Table[string, bool]) =
 103   let url =
 104     if find(url, PEERTUBE_REGEX) != -1 and isInstalled("webtorrent"):
 105       getPeerTubeMagnetLink(url)
 106     else: url
 107   if url.startswith("magnet:") or url.endswith(".torrent"):
 108     if options["musicOnly"]:
 109       # TODO Replace with WebTorrent once it supports media player options
 110       discard execShellCmd(&"peerflix '{url}' -a --{player} -- --no-video")
 111     else:
 112       # WebTorrent is so much faster!
 113       discard execProcess("webtorrent", args=[url, &"--{player}"], options=processOptions)
 114   else:
 115     play(player, options, url)
 116
 117
 118 proc directDownload*(url: string, musicOnly: bool) =
 119   let args =
 120     if musicOnly: buildMusicDownloadArgs(url)
 121     else: buildVideoDownloadArgs(url)
 122   if isInstalled("aria2c"):
 123     discard execShellCmd(&"youtube-dl {args.join(\" \")} --external-downloader aria2c --external-downloader-args '-x 16 -s 16 -k 2M'")
 124   else:
 125     discard execShellCmd(&"youtube-dl {args.join(\" \")}")
 126
 127
 128 proc offerSelection(searchResults: SearchResults, options: Table[string, bool], selectionRange: SelectionRange): string =
 129   if options["feelingLucky"]: "0"
 130   else:
 131     presentVideoOptions(searchResults[selectionRange.begin .. selectionRange.until])
 132     stdout.styledWrite(fgYellow, "Choose video number: ")
 133     readLine(stdin)
 134
 135
 136 proc handleUserInput(searchResult: SearchResult, options: Table[string, bool], player: string) =
 137   if options["download"]:
 138     if options["musicOnly"]:
 139       download(buildMusicDownloadArgs(searchResult.url), searchResult.title)
 140     else:
 141       download(buildVideoDownloadArgs(searchResult.url), searchResult.title)
 142   else:
 143     play(player, options, searchResult.url, searchResult.title)
 144
 145
 146 proc present*(searchResults: SearchResults, options: Table[string, bool], selectionRange: SelectionRange, player: string) =
 147   ##[ Continuously present options till the user quits the application
 148
 149         selectionRange: Currently available range to choose from depending on pagination
 150   ]##
 151
 152   let userInput = offerSelection(searchResults, options, selectionRange)
 153
 154   case userInput
 155   of "all":
 156     for selection in selectionRange.begin .. selectionRange.until:
 157       handleUserInput(searchResults[selection], options, player)
 158     quit(0)
 159   of "n":
 160     if selectionRange.until + 1 < len(searchResults):
 161       let newSelectionRange = (selectionRange.until + 1, min(len(searchResults) - 1, selectionRange.until + limit))
 162       present(searchResults, options, newSelectionRange, player)
 163     else:
 164       present(searchResults, options, selectionRange, player)
 165   of "p":
 166     if selectionRange.begin > 0:
 167       let newSelectionRange = (selectionRange.begin - limit, selectionRange.until - limit)
 168       present(searchResults, options, newSelectionRange, player)
 169     else:
 170       present(searchResults, options, selectionRange, player)
 171   of "q":
 172     quit(0)
 173   else:
 174     let searchResult = searchResults[selectionRange.begin .. selectionRange.until][parseInt(userInput)]
 175     handleUserInput(searchResult, options, player)
 176     if options["feelingLucky"]:
 177       quit(0)
 178     else:
 179       present(searchResults, options, selectionRange, player)