src/lib.nim

   1 import
   2   htmlparser,
   3   httpClient,
   4   os,
   5   osproc,
   6   sequtils,
   7   sugar,
   8   strformat,
   9   std/[terminal],
  10   strformat,
  11   strtabs,
  12   strutils,
  13   tables,
  14   uri,
  15   xmltree
  16
  17 import config
  18
  19 type
  20   Options* = Table[string, bool]
  21   SearchResult* = tuple[title: string, url: string]
  22   SearchResults* = seq[tuple[title: string, url: string]]
  23   CommandLineOptions* = tuple[searchQuery: string, options: Options]
  24   SelectionRange* = tuple[begin: int, until: int]
  25
  26 # poEchoCmd can be added to options for debugging
  27 let processOptions = {poStdErrToStdOut, poUsePath}
  28
  29 proc selectMediaPlayer*(): string =
  30   let availablePlayers = filterIt(supportedPlayers, execProcess("which " & it).len != 0)
  31   if len(availablePlayers) == 0:
  32     stderr.writeLine &"Please install one of the supported media players: {supportedPlayers}"
  33     raise newException(OSError, "No supported media player found")
  34   else:
  35     return availablePlayers[0]
  36
  37 proc getYoutubePage*(searchQuery: string): string =
  38   let queryParam = encodeUrl(searchQuery)
  39   let client = newHttpClient()
  40   let response = get(client, &"https://www.youtube.com/results?hl=en&search_query={queryParam}")
  41   return $response.body
  42
  43 func extractTitlesAndUrls*(html: string): SearchResults =
  44   {.noSideEffect.}:
  45     parseHtml(html).findAll("a").
  46       filter(a => "watch" in a.attrs["href"] and a.attrs.hasKey "title").
  47       map(a => (a.attrs["title"], "https://www.youtube.com" & a.attrs["href"]))
  48
  49 proc presentVideoOptions*(searchResults: SearchResults) =
  50   eraseScreen()
  51   for index, (title, url) in searchResults:
  52     styledEcho $index, ". ", styleBright, fgMagenta, title, "\n", resetStyle, fgCyan, url, "\n"
  53
  54 func isPlaylist(url: string): bool =
  55   # Identifies if video is part of a playlist
  56   # Only YouTube playlists are supported for now
  57   "www.youtube.com" in url and "&list=" in url
  58
  59 # This is a pure function with no side effects
  60 func buildPlayerArgs(url: string, options: Table[string, bool], player: string): seq[string] =
  61   let url =
  62     # Playlists are only supported for MPV player
  63     if isPlaylist(url) and player == "mpv":
  64       "https://www.youtube.com/playlist?" & url.split('&')[1]
  65     else: url
  66   let musicOnly = if options["musicOnly"]: "--no-video" else: ""
  67   let fullScreen = if options["fullScreen"]: "--fullscreen" else: ""
  68   return filterIt([url, musicOnly, fullScreen], it != "")
  69
  70 proc play*(player: string, options: Table[string, bool], url: string, title: string = "") =
  71   let args = buildPlayerArgs(url, options, player)
  72   if title != "":
  73     styledEcho "\n", fgGreen, "Playing ", styleBright, fgMagenta, title
  74   if "--no-video" in args:
  75     discard execShellCmd(&"{player} {args.join(\" \")}")
  76   else:
  77     discard execProcess(player, args=args, options=processOptions)
  78
  79 func buildMusicDownloadArgs*(url: string): seq[string] =
  80   {.noSideEffect.}:
  81     let downloadLocation = &"'{expandTilde(musicDownloadDirectory)}/%(title)s.%(ext)s'"
  82     return @["--ignore-errors", "-f", "bestaudio", "--extract-audio", "--audio-format", "mp3", "--audio-quality", "0", "-o", downloadLocation, url]
  83
  84 func buildVideoDownloadArgs*(url: string): seq[string] =
  85   {.noSideEffect.}:
  86     let downloadLocation = &"'{expandTilde(videoDownloadDirectory)}/%(title)s.%(ext)s'"
  87     return @["-f", "best", "-o", downloadLocation, url]
  88
  89 proc download*(args: openArray[string], title: string) =
  90   styledEcho "\n", fgGreen, "Downloading ", styleBright, fgMagenta, title
  91   discard execShellCmd(&"youtube-dl {args.join(\" \")}")
  92
  93 func urlLongen(url: string): string =
  94   url.replace("youtu.be/", "www.youtube.com/watch?v=")
  95
  96 func stripZshEscaping(url: string): string =
  97   url.replace("\\", "")
  98
  99 func sanitizeURL*(url: string): string =
 100   urlLongen(stripZshEscaping(url))
 101
 102 proc directPlay*(url: string, player: string, options: Table[string, bool]) =
 103   if url.startswith("magnet:") or url.endswith(".torrent"):
 104     if options["musicOnly"]:
 105       # TODO Replace with WebTorrent once it supports media player options
 106       discard execShellCmd(&"peerflix '{url}' -a --{player} -- --no-video")
 107     else:
 108       # WebTorrent is so much faster!
 109       discard execProcess("webtorrent", args=[url, &"--{player}"], options=processOptions)
 110   else:
 111     play(player, options, url)
 112
 113 proc directDownload*(url: string, musicOnly: bool) =
 114   let args =
 115     if musicOnly: buildMusicDownloadArgs(url)
 116     else: buildVideoDownloadArgs(url)
 117   discard execShellCmd(&"youtube-dl {args.join(\" \")}")
 118
 119 proc offerSelection(searchResults: SearchResults, options: Table[string, bool], selectionRange: SelectionRange): string =
 120   if options["feelingLucky"]: "0"
 121   else:
 122     presentVideoOptions(searchResults[selectionRange.begin .. selectionRange.until])
 123     stdout.styledWrite(fgYellow, "Choose video number: ")
 124     readLine(stdin)
 125
 126 proc handleUserInput(searchResult: SearchResult, options: Table[string, bool], player: string) =
 127   if options["download"]:
 128     if options["musicOnly"]:
 129       download(buildMusicDownloadArgs(searchResult.url), searchResult.title)
 130     else:
 131       download(buildVideoDownloadArgs(searchResult.url), searchResult.title)
 132   else:
 133     play(player, options, searchResult.url, searchResult.title)
 134
 135 proc present*(searchResults: SearchResults, options: Table[string, bool], selectionRange: SelectionRange, player: string) =
 136   #[ Continuously present options till the user quits the application
 137        selectionRange: Currently available range to choose from depending on pagination
 138   ]#
 139
 140   let userInput = offerSelection(searchResults, options, selectionRange)
 141
 142   case userInput
 143   of "all":
 144     for selection in selectionRange.begin .. selectionRange.until:
 145       handleUserInput(searchResults[selection], options, player)
 146     quit(0)
 147   of "n":
 148     if selectionRange.until + 1 < len(searchResults):
 149       let newSelectionRange = (selectionRange.until + 1, min(len(searchResults) - 1, selectionRange.until + limit))
 150       present(searchResults, options, newSelectionRange, player)
 151     else:
 152       present(searchResults, options, selectionRange, player)
 153   of "p":
 154     if selectionRange.begin > 0:
 155       let newSelectionRange = (selectionRange.begin - limit, selectionRange.until - limit)
 156       present(searchResults, options, newSelectionRange, player)
 157     else:
 158       present(searchResults, options, selectionRange, player)
 159   of "q":
 160     quit(0)
 161   else:
 162     let searchResult = searchResults[selectionRange.begin .. selectionRange.until][parseInt(userInput)]
 163     handleUserInput(searchResult, options, player)
 164     if options["feelingLucky"]:
 165       quit(0)
 166     else:
 167       present(searchResults, options, selectionRange, player)