pagination: "p" takes to the previous page of results

[nimcoon.git] / src / nimcoon.nim

import
  os,
  parseopt,
  std/[terminal],
  strformat,
  strutils,
  tables

import config
import lib


proc parseArguments(): CommandLineOptions =
  var
    searchQuery = ""
    options = to_table({"musicOnly": false, "feelingLucky": false, "fullScreen": false, "download": false})

  for kind, key, value in getopt():
    case kind
    of cmdArgument:
      searchQuery = key
    of cmdShortOption, cmdLongOption:
      case key
      of "m", "music": options["musicOnly"] = true
      of "l", "lucky": options["feelingLucky"] = true
      of "f", "full-screen": options["fullScreen"] = true
      of "d", "download": options["download"] = true
    of cmdEnd: discard

  return (searchQuery, options)


proc isValidOptions*(options: Options): bool =
  # Check for invalid combinations of options
  var invalidCombinations = [("musicOnly", "fullScreen"), ("download", "fullScreen")]
  for combination in invalidCombinations:
    if options[combination[0]] and options[combination[1]]:
     stderr.writeLine fmt"Incompatible options provided: {combination[0]} and {combination[1]}"
     return false
  return true


proc main() =
  let
    player = selectMediaPlayer()
    (searchQuery, options) = parseArguments()

  if(not isValidOptions(options)):
    quit(1)

  if searchQuery.startswith("https:") or searchQuery.startswith("magnet:"):
    if options["download"]:
      directDownload(sanitizeURL(searchQuery), options["musicOnly"])
    else:
      directPlay(sanitizeURL(searchQuery), player, options["musicOnly"])
    quit(0)

  let searchResults = extractTitlesAndUrls(getYoutubePage(searchQuery))

  # Currently available range to choose from depending on pagination
  var selectionRange: SelectionRange = (0, limit-1) # Nim decided to deviate from Python ranges here

  proc offerSelection(): string =
    if options["feelingLucky"]: "0"
    else:
      presentVideoOptions(searchResults[selectionRange.begin .. selectionRange.until])
      stdout.styledWrite(fgYellow, "Choose video number: ")
      readLine(stdin)

  # This is a pure function with no side effects
  func buildPlayerArgs(number: int): seq[string] =
    var args = @[searchResults[number].url]
    if options["musicOnly"]: args.add("--no-video")
    if options["fullScreen"]: args.add("--fullscreen")
    return args

  proc handleUserInput(selection: int) =
    if options["download"]:
      if options["musicOnly"]:
        download(buildMusicDownloadArgs(searchResults[selection].url), searchResults[selection].title)
      else:
        download(buildVideoDownloadArgs(searchResults[selection].url), searchResults[selection].title)
    else:
      play(player, buildPlayerArgs(selection), searchResults[selection].title)


  while(true):
    let userInput = offerSelection()

    case userInput
    of "all":
      for selection in selectionRange.begin .. selectionRange.until:
        # TODO `spawn` this?
        handleUserInput(selection)
    of "n":
      if selectionRange.until + 1 < len(searchResults):
        selectionRange = (selectionRange.until + 1, min(len(searchResults) - 1, selectionRange.until + limit))
      continue
    of "p":
      if selectionRange.begin > 0:
        selectionRange = (selectionRange.begin - limit, selectionRange.until - limit)
      continue
    of "q":
      quit(0)

    # Play the video using the preferred/available media player
    let videoNumber = parseInt(userInput)
    handleUserInput(videoNumber)
    if options["feelingLucky"]:
      break


when isMainModule:
  main()