Add PeerTube support

[nimcoon.git] / clitube.nim

import htmlparser
import httpClient
import parseopt
import osproc
import sequtils, sugar
import strformat
import std/[terminal]
import strtabs
import strutils
import uri
import xmltree

import preferences

type SearchResult = tuple[title: string, url: string]

proc selectMediaPlayer(): string =
  let availablePlayers = filterIt(supportedPlayers, execProcess("which " & it).len != 0)
  if len(availablePlayers) == 0:
    stderr.writeLine &"Please install one of the supported media players: {supportedPlayers}"
    raise newException(OSError, "No supported media player found")
  else:
    return availablePlayers[0]

proc getYoutubePage(searchQuery: string): string =
  let queryParam = encodeUrl(searchQuery)
  let client = newHttpClient()
  let response = get(client, &"https://www.youtube.com/results?hl=en&search_query={queryParam}")
  return $response.body

proc extractTitlesAndUrls(htmlFile: string): seq[SearchResult] =
  parseHtml(htmlFile).findAll("a").
    filter(a => "watch" in a.attrs["href"] and a.attrs.hasKey "title").
    map(a => (a.attrs["title"], "https://www.youtube.com" & a.attrs["href"]))[..(limit-1)]

proc presentVideoOptions(searchResults: seq[SearchResult]) =
  echo ""
  for index, (title, url) in searchResults:
    styledEcho $index, ". ", styleBright, fgMagenta, title, "\n", resetStyle, fgCyan, url, "\n"

let player = selectMediaPlayer()

var searchQuery = ""
var musicOnly = false
var feelingLucky = false

for kind, key, value in getopt():
  case kind
  of cmdArgument:
     searchQuery = key
  of cmdShortOption, cmdLongOption:
    case key
    of "m", "music": musicOnly = true
    of "l", "lucky": feelingLucky = true
  of cmdEnd:
    discard


if "?watch" in searchQuery or "videos/watch" in searchQuery :
  discard execProcess(&"{player} {searchQuery}")
  quit(0)


let searchResults = extractTitlesAndUrls(getYoutubePage(searchQuery))

let number =
  if feelingLucky:
    0
  else:
    presentVideoOptions(searchResults)
    stdout.styledWrite(fgYellow, "Choose video number: ")
    parseInt(readLine(stdin))

styledEcho "\n", fgGreen, "Playing ", styleBright, fgMagenta, searchResults[number].title

var command = @[player, searchResults[number].url]

if musicOnly:
  command.add("--no-video")

# Play the video using the preferred/available media player
discard execProcess(command.join(" "))