Get rid of subprocess call to unzip

[babashka-scripts.git] / ebook-to-audio-book.clj

#! /usr/bin/env bb

; A utility to listen to your ebooks using TTS programs

(import '[java.nio.file Files FileSystems CopyOption])

(require '[babashka.process :as p]
         '[clojure.java.io :as io]
         '[clojure.string :refer [split]])

;; TODO Check if all required utilities are installed

;; TODO Allow voice selection
(println "Selected voice is Samantha")

;; TODO Use festival-tts or say depending on OS


(defn run-cmd
  [command]
  (->> command
       p/process
       :out
       slurp))

(defn extract-file-from-zip
  [zip-file-name source destination]
  (let [zip-file (io/file zip-file-name)
        src (io/file source)
        dest (io/file destination)
        fs (FileSystems/newFileSystem (.toPath zip-file) nil)
        file-in-zip (.getPath fs source (into-array String []))]
    (Files/copy file-in-zip (.toPath dest)
                (into-array CopyOption []))))

(let [book-file (first *command-line-args*)
      title (first (split book-file #"\."))
      txtz-file (str title ".txtz")
      txt-file (str title ".txt")
      aiff-file (str title ".aiff")
      mp3-file (str title ".mp3")]
  (println "Converting to text...")
  (run-cmd ["ebook-convert" book-file txtz-file])
  (extract-file-from-zip txtz-file "index.txt" txt-file)
  (println "Converting text to audio. Don't hold your breath!")
  (run-cmd ["say" "-f" txt-file "-o" aiff-file])
  (println "Creating mp3 file...")
  (run-cmd ["ffmpeg" "-i" aiff-file mp3-file])
  (println "Cleaning up...")
  (run! #(io/delete-file %) [txtz-file txt-file aiff-file])
  (println (str "Done! Check out " mp3-file)))