lib: Use syntactic sugar

[babashka-scripts.git] / update-babashka.clj

#! /usr/bin/env bb

(require '[cheshire.core :as json]
         '[org.httpkit.client :as http]
         '[babashka.fs :as fs]
         '[clojure.java.io :as io]
         '[lib :refer [download-binary expand-home extract-file-from-zip]])

(defn babashka-latest-version
  []
  (-> @(http/get "https://api.github.com/repos/babashka/babashka/tags")
      :body
      (json/parse-string true)
      first
      :name
      (subs 1)))

(defn get-download-url
  [version architecture]
  (str "https://github.com/babashka/babashka/releases/download/v"
       version
       "/babashka-"
       version
       "-"
       architecture
       ".zip"))

(defn check-latest
  [version]
  (when (= (System/getProperty "babashka.version") version)
    (println "Already using the latest version.")
    (System/exit 0)))

(defn download-latest
  [version architecture output]
  (let [url (get-download-url version architecture)]
    (download-binary url output)))

(defn update-babashka
  []
  (let [architecture "linux-amd64"  ;; TODO support other architectures
        zip-file "babashka.zip"
        destination (expand-home "~/bin/bb")
        version (babashka-latest-version)]
    (println (str "Latest version is " version))
    (check-latest version)
    (println "Updating...")
    (download-latest version architecture zip-file)
    (extract-file-from-zip zip-file "bb" destination)
    (fs/set-posix-file-permissions destination "rwxr-xr-x")
    (io/delete-file zip-file)
    (println "Done!")))

(when (= *file* (System/getProperty "babashka.file")) (update-babashka))