Continuously keep playing till I press "q"

[nimcoon.git] / nimcoon.nim

import
  parseopt,
  std/[terminal],
  strutils

import lib

proc parseOptions(): CommandLineOptions =
  var
    searchQuery = ""
    musicOnly = false
    feelingLucky = false
    fullScreen = false

  for kind, key, value in getopt():
    case kind
    of cmdArgument:
      searchQuery = key
    of cmdShortOption, cmdLongOption:
      case key
      of "m", "music": musicOnly = true
      of "l", "lucky": feelingLucky = true
      of "f", "full-screen": fullScreen = true
    of cmdEnd:
      discard

  return (searchQuery, musicOnly, feelingLucky, fullScreen)


proc main() =
  let
    player = selectMediaPlayer()
    (searchQuery, musicOnly, feelingLucky, fullScreen) = parseOptions()

  if searchQuery.startswith("https:") or searchQuery.startswith("magnet:"):
    directPlay(searchQuery, player)

  let searchResults = extractTitlesAndUrls(getYoutubePage(searchQuery))

  proc getUserInput(): string =
    if feelingLucky: "0"
    else:
      presentVideoOptions(searchResults)
      stdout.styledWrite(fgYellow, "Choose video number: ")
      readLine(stdin)

  # This is a pure function with no side effects
  func buildArgs(number: int): seq[string] =
    var args = @[searchResults[number].url]
    if musicOnly: args.add("--no-video")
    if fullScreen: args.add("--fullscreen")
    return args

  while(true):
    let userInput = getUserInput()
    if userInput == "q":
      break

    let videoNumber = parseInt(userInput)
    styledEcho "\n", fgGreen, "Playing ", styleBright, fgMagenta, searchResults[videoNumber].title

    # Play the video using the preferred/available media player
    play(player, buildArgs(videoNumber))
    if feelingLucky:
      break


when isMainModule:
  main()